Disabling programs in FSX

[vortex681 806]

That sounds like an answer! The trouble is I go a bit all unnecessary when I hear the words 'batch file'.

 

Ron, this is the batch file I use to start FSX:

 

 

@echo off

cls

echo.

echo.

echo     [1] - Start FSX

echo     [2] - Start FSX with FSXWX

echo     [3] - Start FSX with RemoteFlight Server

echo     [4] - Start FSX with FSXWX and RemoteFlight Server

echo     [5] - Start Ideal Flight

echo     [6] - Exit without doing anything

echo.

 

set /p selection=

 

MIN

 

if %selection%==1 goto fsx

if %selection%==2 goto wx

if %selection%==3 goto rf

if %selection%==4 goto everything

if %selection%==5 goto ideal

exit

 

:everything

rem start RemoteFlight Server

cd /D "E:\Program Files (x86)\Utilities\"

start RemoteFlightServer.exe

timeout /t 5

 

:wx

rem start FSXWX

cd /D "E:\FSX Aircraft\"

start FSXWX.exe

 

goto fsx

 

:rf

rem start RemoteFlight Server

cd /D "E:\Program Files (x86)\Utilities\"

start RemoteFlightServer.exe

timeout /t 5

 

:fsx

rem start FSX

 

taskkill /fi "STATUS eq RUNNING" /im outlook.exe

taskkill /fi "STATUS eq RUNNING" /im firefox.exe

timeout /t 3

 

cd /D "C:\Program Files (x86)\Microsoft Games\Microsoft Flight Simulator X\"

start /wait fsx.exe

 

taskkill /fi "STATUS eq RUNNING" /im FSXWX.exe

cd /D "C:\Program Files (x86)\Microsoft Office\Office14\"

start OUTLOOK.EXE

exit

 

:ideal

rem start Ideal Flight

 

MIN

 

taskkill /fi "STATUS eq RUNNING" /im outlook.exe

taskkill /fi "STATUS eq RUNNING" /im firefox.exe

timeout /t 3

 

cd /D "E:\FSX Aircraft\"

start FSXWX.exe

 

cd /D "C:\Program Files (x86)\Ideal Flight 10\"

start /wait iflight10.exe

 

exit

 

 

 

The MIN command minimises the command window but is not built into Windows. You can download it free (with some other useful utilities) as part of cmdutils.zip from http://www.paulsadowski.com/wsh/cmdprogs.htm. You should extract MIN.exe and put it somewhere in the Windows path - I put it in C:\Windows\system32.

 

The start command starts the selected programs, taskkill looks to see if a program is running and, if so, shuts it down. The wait command before fsx.exe waits for FSX to close and then continues with the batch file to restart software (you can start/restart as much or as little as you like). Some of the timeouts are to let the programs start properly before moving on.

 

Cut & paste the text above from @echo off to the final exit command into notepad (or some other suitable editor) and tweak the paths and programs you want to use. You need to think carefully about the order in which you place the entries to start and stop programs to keep the batch file logical. When you're happy, save it as something like fsxstart.bat. Run the batch file as an administrator and it should then avoid most hiccups in Windows. I have used some bits of batch files posted by other people (but can't remember their names - my apologies to them) and added bits to streamline the process a little. Hope this gives you some ideas. Let me know if you have any questions.

 

PS - I have the paid version of Malwarebytes which runs in the background when I use FSX and have yet to notice any problems with it.

[Ron Attwood 3,464]

Vortex, I really do appreciate the trouble you've gone to, but I'm only 2 days into my course on Sanskrit!  :blush:  To be honest I've never found any specific problem with it either. This started out as a 'I wonder if that'll make a difference' kinda thing.

I'm happy enough to turn it off and switch it on as required. That's all.

Ron

[vortex681 806]

Vortex, I really do appreciate the trouble you've gone to, but I'm only 2 days into my course on Sanskrit!  :blush:  To be honest I've never found any specific problem with it either. This started out as a 'I wonder if that'll make a difference' kinda thing.

I'm happy enough to turn it off and switch it on as required. That's all.

Ron

 

Maybe it will be of use to someone else. It's my solution to being to old to remember to stop and start things!